package
{
    import flash.display.Loader;
    import flash.display.SimpleButton;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.events.MouseEvent;
    import flash.net.URLRequest;
    import flash.system.ApplicationDomain;
    import flash.text.Font;
    import flash.text.TextField;
    import flash.text.TextFormat;
    import kr.asduck.debug.echo;


/**
* Use embeded fonts by loading swf file
* ( font 가 embeded 된 swf 를 load 하여 swf file 내의 font를 사용하는 Sample )
* font embeded 시 용량이 커지는 문제를 swf file 을 load 하여 사용하는 방식으로 해결
* 단, 도메인이 서로 다를 경우 이 방법으로는 사용이 불가능하다. ( applicationDomain 부분에 대한 설정이 필요함 )
*
* @author duck
* 2008.04.29
*/ 
    public class SampleEmbededFont extends Sprite
    {
        public var txt:TextField;
        public var btnFontType1:SimpleButton, btnFontType2:SimpleButton;

        private var arrFontType:Array;
        private var arrFontList:Array;
        private var swfLoader:Loader;

        public function SampleEmbededFont()
        {
            // ** default setting ** //

                this.arrFontType = [ "font_BrushScriptMT", "font_MalgunGD" ];
                this.arrFontList = new Array();

                this.txt.text = "This is sample of embeded font";



                // ** swf file load ** //

                var swfPath:String = "http://asduck.kr/step/step5/embededFonts.swf";

                this.swfLoader = new Loader();
                this.swfLoader.contentLoaderInfo.addEventListener( Event.COMPLETE, swfLoadComplete );
                this.swfLoader.contentLoaderInfo.addEventListener( IOErrorEvent.IO_ERROR, swfLoadFail );
                this.swfLoader.load( new URLRequest( swfPath ) );

                echo( "\n1. swf load" );
                echo( "\t - swf load : loading..." );

        }

        private function swfLoadComplete( e:Event ):void
        {
            echo( "swf load : load complete!" );

            this.btnFontType1.addEventListener( MouseEvent.CLICK, changeFontListener );
            this.btnFontType2.addEventListener( MouseEvent.CLICK, changeFontListener );



            // ** embeded fonts setting ** //

            var i:int;
            for( i=0; i<this.arrFontType.length; i++ )
            {
                var loadedFont:Class =                         this.swfLoader.contentLoaderInfo.applicationDomain.getDefinition( this.arrFontType[i] ) as Class;
                Font.registerFont( loadedFont );
            }

            this.arrFontList = Font.enumerateFonts( false );
        }

        private function swfLoadFail( e:IOErrorEvent ):void
        {
            echo( "swf load : load fail by IOError!" );
        }



        /**
        *
        * Change font type listener
        *
        */ 
        private function changeFontListener( e:MouseEvent ):void
        {
            var tmpStr:String = e.target.name;
            var index:int = int( tmpStr.substr( tmpStr.length - 1, tmpStr.length )) - 1;


            // ** apply embeded font to the TextField ** //

            var format:TextFormat = new TextFormat();
            format.font = this.arrFontList[index].fontName;

            echo( "\nfont_name : ", this.arrFontList[index].fontName );

            this.txt.embedFonts = true;
            this.txt.setTextFormat( format );
        }
    }
}